cmake_minimum_required(VERSION 3.30)
project(fennec)

# External dependencies should be loaded here

# SDL is a dependency of the project, added as a git submodule
add_subdirectory(external/sdl)

# CppTrace is a dependency of the project, added as a git submodule
add_subdirectory(external/cpptrace)

set(CMAKE_CXX_STANDARD 26)
set(CMAKE_C_STANDARD 26)

# find dependencies
find_package(Doxygen)

# any necessary include directories
include_directories(include)
include_directories(external/cpptrace/include)
include_directories(external/sdl/include)

# Metaprogramming is a dependency for generating various type info before compilation of the engine.
add_subdirectory(metaprogramming)

string(TOLOWER ${CMAKE_BUILD_TYPE} FENNEC_BUILD_NAME)

message(STATUS "OS: ${CMAKE_SYSTEM_NAME}")
message(STATUS "Build: ${FENNEC_BUILD_NAME}")

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/lib/${FENNEC_BUILD_NAME})
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/lib/${FENNEC_BUILD_NAME})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_SOURCE_DIR}/bin/${FENNEC_BUILD_NAME})

add_library(fennec STATIC

# CORE =================================================================================================================
        include/fennec/core/engine.h source/core/engine.cpp


# CONTAINERS ===========================================================================================================
        include/fennec/containers/array.h
        include/fennec/containers/dynarray.h


# LANG =================================================================================================================
        include/fennec/lang/lang.h
        include/fennec/lang/metaprogramming.h

        include/fennec/lang/bits.h
        include/fennec/lang/constants.h
        include/fennec/lang/conditional_types.h
        include/fennec/lang/intrinsics.h
        include/fennec/lang/limits.h
        include/fennec/lang/numeric_transforms.h
        include/fennec/lang/sequences.h
        include/fennec/lang/type_traits.h
        include/fennec/lang/type_transforms.h
        include/fennec/lang/types.h
        include/fennec/lang/utility.h
        include/fennec/lang/type_sequences.h
        include/fennec/lang/integer.h

        include/fennec/lang/detail/__bits.h
        include/fennec/lang/detail/__int.h
        include/fennec/lang/detail/__numeric_transforms.h
        include/fennec/lang/detail/__stdlib.h
        include/fennec/lang/detail/__type_traits.h
        include/fennec/lang/detail/__type_sequences.h

        include/fennec/lang/assert.h source/lang/assert.cpp


# MEMORY ===============================================================================================================
        include/fennec/memory/new.h source/memory/new.cpp

        include/fennec/memory/common.h
        include/fennec/memory/allocator.h
        include/fennec/memory/memory.h
        include/fennec/memory/pointers.h
        include/fennec/memory/ptr_traits.h

        include/fennec/memory/detail/__ptr_traits.h

# DEBUG ================================================================================================================
        source/debug/assert_impl.cpp


# MATH =================================================================================================================
        include/fennec/math/math.h

        include/fennec/math/scalar.h

        include/fennec/math/vector.h
        include/fennec/math/vector_base.h
        include/fennec/math/vector_traits.h
        include/fennec/math/vector_storage.h

        include/fennec/math/swizzle.h
        include/fennec/math/swizzle_storage.h

        include/fennec/math/matrix.h

        include/fennec/math/common.h
        include/fennec/math/exponential.h
        include/fennec/math/geometric.h
        include/fennec/math/trigonometric.h
        include/fennec/math/relational.h

        include/fennec/math/detail/__fwd.h
        include/fennec/math/detail/__math.h
        include/fennec/math/detail/__matrix.h
        include/fennec/math/detail/__types.h
        include/fennec/math/detail/__vector_traits.h

        include/fennec/math/ext/constants.h

# FPROC ================================================================================================================

        # Strings
        include/fennec/fproc/strings/cstring.h
        include/fennec/fproc/strings/locale.h
        include/fennec/fproc/strings/string.h

        include/fennec/fproc/strings/detail/__ctype.h

        # IO
        include/fennec/fproc/io/file.h source/fproc/io/file.cpp
        include/fennec/fproc/io/common.h
        source/fproc/io/common.cpp

)

# add metaprogramming templates as a dependency and also force documentation to be generated when fennec is compiled
if(DOXYGEN_FOUND)
    add_dependencies(fennec fennecdocs metaprogramming SDL3-shared cpptrace::cpptrace)
else()
    add_dependencies(fennec metaprogramming SDL3-shared cpptrace::cpptrace)
endif()

# Compiler Warning Flags
if(MSVC)
    add_compile_options("/W4" "/WX") # All MSVC Warnings throw as Errors
else()
    add_compile_options("-Wall" "-Wextra" "-pedantic" "-Werror") # All gcc/etc. Warnings throw as errors
endif()

target_compile_options(fennec PUBLIC "-mavx" "-mavx2" "-mavx512f") # SIMD Instructions, automatic vectorization will occur

target_link_options(fennec PRIVATE "-nostdlib" "-fno-exceptions" "-fno-rtti" "-fdiagnostics-all-candidates") # Do not compile base fennec library with c++ stdlib
# fennec does not use the C++ stdlib because it is bloated, difficult to read, and implementation defined.
# This implementation is designed to be as readable as possible, and expose information that would otherwise be obfuscated

target_link_libraries(fennec PRIVATE SDL3-shared cpptrace::cpptrace)


# add the test suite as a sub-project
add_subdirectory(test)



# DOXYGEN ==============================================================================================================
# https://vicrucann.github.io/tutorials/quick-cmake-doxygen/

file(COPY logo DESTINATION docs/logo)

if(DOXYGEN_FOUND)
    set(DOXY_OUTPUT_DIR "${PROJECT_SOURCE_DIR}/docs")
    get_filename_component(DOXYGEN_PROJECT_NAME ${PROJECT_SOURCE_DIR} NAME) # Set Doxy Project name to the name of the root dir
    set(DOXYGEN_CONFIG_IN "${PROJECT_SOURCE_DIR}/doxy/Doxyfile.in") # Input config file with preprocessor arguments
    set(DOXYGEN_CONFIG_OUT "${PROJECT_SOURCE_DIR}/doxy/Doxyfile") # Generated config file from input

    configure_file(${DOXYGEN_CONFIG_IN} ${DOXYGEN_CONFIG_OUT} @ONLY) # Execute preprocessing step
    message("Doxygen Build Started.")


    # Target for building docs
    add_custom_target(fennecdocs ALL
            COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_CONFIG_OUT}
            WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
            COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/logo/raster.png
                                             ${DOXY_OUTPUT_DIR}/logo/raster.png
            COMMENT "Generating Doxygen Documentation"
            VERBATIM)

    add_dependencies(fennecdocs fennecdocs-clean)

    # Target for cleaning docs
    add_custom_target(fennecdocs-clean ALL
            COMMAND ${CMAKE_COMMAND} -E remove -f "${PROJECT_SOURCE_DIR}/docs"
            COMMENT "Cleaning Doxygen Documentation"
            VERBATIM)
else()
    message("Doxygen not found.")
endif()
